Terraform ve Firebase'i kullanmaya başlayın

Firebase, Terraform'u desteklemeye başlıyor. Belirli kaynakların sağlandığı ve hizmetlerin etkinleştirildiği Firebase projeleri oluşturma sürecini otomatik hâle getirmek ve standartlaştırmak isteyen bir ekibin üyesiyseniz Firebase ile Terraform'u kullanmak sizin için uygun olabilir.

Terraform'u Firebase ile kullanmanın temel iş akışı şunları içerir:

  • Sağlamak istediğiniz altyapıyı (yani sağlamak istediğiniz kaynakları ve etkinleştirmek istediğiniz hizmetleri) belirten bir Terraform yapılandırma dosyası (.tf dosyası) oluşturma ve özelleştirme.

  • .tf dosyasında belirtilen altyapıyı sağlamak için Terraform ile arayüz oluşturan gcloud CLI komutlarını kullanma

Terraform ve Firebase ile neler yapabilirsiniz?

Bu kılavuzdaki örnek genelleştirilmiş iş akışı, Android uygulaması içeren yeni bir Firebase projesi oluşturur. Ancak Terraform ile çok daha fazlasını yapabilirsiniz. Örneğin:

  • Terraform'u kullanarak mevcut altyapıyı silme ve değiştirme

  • Terraform'u kullanarak ürüne özel yapılandırmaları ve görevleri yönetebilirsiniz. Örneğin:

    • Firebase Authentication oturum açma sağlayıcısı etkinleştiriliyor.
    • Cloud Storage paketleri veya veritabanı örnekleri oluşturma ve bunlar için Firebase Security Rules dağıtma.
    • Firebase App Hosting arka uç, derleme ve diğer ilgili kaynaklar oluşturuluyor.

Tüm bu görevleri gerçekleştirmek için standart Terraform yapılandırma dosyalarını ve komutlarını kullanabilirsiniz. Bu konuda size yardımcı olmak için yaygın kullanım alanlarına yönelik örnek Terraform yapılandırma dosyaları hazırladık.


Firebase ile Terraform'u kullanmaya yönelik genel iş akışı

Ön koşullar

Bu kılavuz, Terraform'un Firebase ile kullanımına giriş niteliğindedir. Bu nedenle, Terraform hakkında temel düzeyde bilgi sahibi olduğunuz varsayılır. Bu iş akışını başlatmadan önce aşağıdaki ön koşulları tamamladığınızdan emin olun.

  • Terraform'u yükleyin ve resmi eğitimleri kullanarak Terraform hakkında bilgi edinin.

  • Google Cloud CLI aracını yükleyin (gcloud CLI). Kullanıcı hesabı veya hizmet hesabı kullanarak giriş yapın.

1. adım: Terraform yapılandırma dosyası oluşturun ve özelleştirin

Terraform yapılandırma dosyasında iki ana bölüm bulunmalıdır (bunlar aşağıda ayrıntılı olarak açıklanmıştır):

provider cihazınızı ayarlama

Hangi Firebase ürün veya hizmetleri kullanılırsa kullanılsın provider kurulumu gereklidir.

  1. Yerel dizininizde bir Terraform yapılandırma dosyası (main.tf dosyası gibi) oluşturun.

    Bu kılavuzda, hem provider kurulumunu hem de Terraform'un oluşturmasını istediğiniz tüm altyapıyı belirtmek için bu yapılandırma dosyasını kullanacaksınız. Ancak sağlayıcı kurulumunu nasıl dahil edeceğinizle ilgili seçenekleriniz olduğunu unutmayın.

  2. main.tf dosyasının en üstüne aşağıdaki provider kurulumunu ekleyin.

    Firebase'i Terraform ile kullanma özelliğinin beta sürümü olduğundan google-beta sağlayıcısını kullanmanız gerekir. Üretimde kullanırken dikkatli olun.

    # Terraform configuration to set up providers by version.
terraform {
  required_providers {
    google-beta = {
      source  = "hashicorp/google-beta"
      version = "~> 6.0"
    }
  }
}

# Configures the provider to use the resource block's specified project for quota checks.
provider "google-beta" {
  user_project_override = true
}

# Configures the provider to not use the resource block's specified project for quota checks.
# This provider should only be used during project creation and initializing services.
provider "google-beta" {
  alias = "no_user_project_override"
  user_project_override = false
}

    Terraform'u Firebase ile kullanırken projeyle ilgili farklı özellik türleri (bu kılavuzda "kota kontrol projesi" olarak adlandırılan özellik dahil) hakkında daha fazla bilgi edinin.

  3. Yapılandırma dosyanızı tamamlamak ve hangi altyapıyı oluşturacağınızı belirtmek için sonraki bölüme geçin.

resource bloklarını kullanarak hangi altyapının oluşturulacağını belirtme

Terraform yapılandırma dosyanızda (bu kılavuz için main.tf dosyanız), Terraform'un oluşturmasını istediğiniz tüm altyapıyı (yani temel hazırlığını yapmak istediğiniz tüm kaynakları ve etkinleştirmek istediğiniz tüm hizmetleri) belirtmeniz gerekir. Bu kılavuzda, Terraform'u destekleyen tüm Firebase kaynaklarının tam listesini bulabilirsiniz.

  1. main.tf dosyanızı açın.

  2. provider kurulumu altında, aşağıdaki resource blok yapılandırmasını ekleyin.

    Bu temel örnekte yeni bir Firebase projesi oluşturulur ve ardından bu projede bir Firebase Android uygulaması oluşturulur.

    # Terraform configuration to set up providers by version.
...

# Configures the provider to use the resource block's specified project for quota checks.
...

# Configures the provider to not use the resource block's specified project for quota checks.
...

# Creates a new Google Cloud project.
resource "google_project" "default" {
  provider   = google-beta.no_user_project_override

  name       = "Project Display Name"
  project_id = "project-id-for-new-project"
  # Required for any service that requires the Blaze pricing plan
  # (like Firebase Authentication with GCIP)
  billing_account = "000000-000000-000000"

  # Required for the project to display in any list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "default" {
  provider = google-beta.no_user_project_override
  project  = google_project.default.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebase.googleapis.com",
    # Enabling the ServiceUsage API allows the new project to be quota checked from now on.
    "serviceusage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "default" {
  provider = google-beta
  project  = google_project.default.project_id

  # Waits for the required APIs to be enabled.
  depends_on = [
    google_project_service.default
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "default" {
  provider = google-beta

  project      = google_project.default.project_id
  display_name = "My Awesome Android app"
  package_name = "awesome.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.default,
  ]
}

2. adım: Belirtilen altyapıyı oluşturmak için Terraform komutlarını çalıştırın.

main.tf dosyanızda belirtilen kaynakları sağlamak ve hizmetleri etkinleştirmek için main.tf dosyanızla aynı dizinden aşağıdaki komutları çalıştırın. Bu komutlar hakkında ayrıntılı bilgi için Terraform belgelerine bakın.

  1. Dizinde ilk kez Terraform komutları çalıştırıyorsanız yapılandırma dizinini ilk kullanıma hazırlamanız ve Google Terraform sağlayıcısını yüklemeniz gerekir. Bunu yapmak için aşağıdaki komutu çalıştırın:

    terraform init

  2. Aşağıdaki komutu çalıştırarak main.tf dosyanızda belirtilen altyapıyı oluşturun:

    terraform apply

  3. Her şeyin beklendiği gibi temel hazırlığının yapıldığını veya etkinleştirildiğini onaylayın:

    • 1. seçenek: Aşağıdaki komutu çalıştırarak terminalinizde yazdırılan yapılandırmayı görebilirsiniz:

      terraform show

    • 2. seçenek: Firebase projenizi Firebase konsolunda görüntüleyin.


Terraform destekli Firebase kaynakları

Aşağıdaki Firebase ve Google kaynakları Terraform'u destekler. Sürekli yeni kaynaklar ekliyoruz. Terraform ile yönetmek istediğiniz kaynağı görmüyorsanız kısa süre sonra tekrar kontrol ederek kullanılabilir olup olmadığına bakın veya GitHub deposunda sorun bildirerek kaynağı talep edin.

Firebase projesi ve uygulama yönetimi

  • google_firebase_project: Mevcut bir Google Cloud projesinde Firebase hizmetlerini etkinleştirme

  • Firebase Uygulamaları

Firebase Authentication

Henüz desteklenmeyenler:

  • Terraform aracılığıyla çok öğeli kimlik doğrulamasını (MFA) yapılandırma

Firebase App Hosting

Firebase SQL Connect

Firebase Realtime Database

Henüz desteklenmeyenler:

Cloud Firestore

  • google_firestore_database: Cloud Firestore örneği oluşturun.

  • google_firestore_index: Cloud Firestore için verimli sorguları etkinleştirme

  • google_firestore_document: Bir koleksiyondaki belirli bir belgeyle Cloud Firestore örneği oluşturun.

    Önemli: Bu temel belgede gerçek son kullanıcı veya üretim verilerini kullanmayın.

Cloud Storage for Firebase

  • google_firebase_storage_bucket: Mevcut bir Cloud Storage paketini Firebase SDK'ları, kimlik doğrulama ve Firebase Security Rules için erişilebilir hale getirin.

  • google_storage_bucket_object: Cloud Storage paketine nesne ekleme

    Önemli: Bu dosyada gerçek son kullanıcı veya üretim verilerini kullanmayın.

Firebase Security Rules (Cloud Firestore ve Cloud Storage için)

Firebase Realtime Database, Firebase Security Rules için farklı bir temel hazırlık sistemi kullanır.

  • google_firebaserules_ruleset: Bir Cloud Firestore örneği veya Cloud Storage paketi için geçerli olan Firebase Security Rules tanımlayın.

  • google_firebaserules_release: Belirli kural gruplarını bir Cloud Firestore örneğine veya Cloud Storage paketine dağıtma

Firebase App Check

Firebase Extensions


Yaygın kullanım alanları için örnek Terraform yapılandırma dosyaları


Sorun giderme ve SSS