Inizia a utilizzare Terraform e Firebase

Firebase sta iniziando a supportare Terraform. Se fai parte di un team che vuole automatizzare e standardizzare la creazione di progetti Firebase con il provisioning di risorse specifiche e l'attivazione di servizi, l'utilizzo di Terraform con Firebase può essere una buona soluzione per te.

Il flusso di lavoro di base per l'utilizzo di Terraform con Firebase include quanto segue:

  • Creazione e personalizzazione di un file di configurazione Terraform (un file .tf) che specifica l'infrastruttura di cui vuoi eseguire il provisioning (ovvero le risorse di cui vuoi eseguire il provisioning e i servizi che vuoi attivare).

  • Utilizzo dei comandi gcloud CLI che interagiscono con Terraform per eseguire il provisioning dell'infrastruttura specificata nel file .tf.

Cosa puoi fare con Terraform e Firebase?

Il flusso di lavoro generalizzato di esempio in questa guida crea un nuovo progetto Firebase con un'app per Android. Tuttavia, con Terraform puoi fare molto di più, ad esempio:

  • Eliminare e modificare l'infrastruttura esistente utilizzando Terraform.

  • Gestire la configurazione e le attività specifiche del prodotto utilizzando Terraform, ad esempio:

    • Attivazione dei provider di accesso Firebase Authentication.
    • Creazione di bucket o istanze di database Cloud Storage e deployment di Firebase Security Rules per questi elementi.
    • Creazione di backend, build e altre risorse correlate di Firebase App Hosting.

Per eseguire tutte queste attività, puoi utilizzare i file di configurazione e i comandi standard di Terraform. Per aiutarti, abbiamo fornito file di configurazione Terraform di esempio per diversi casi d'uso comuni.


Flusso di lavoro generalizzato per l'utilizzo di Terraform con Firebase

Prerequisiti

Questa guida è un'introduzione all'utilizzo di Terraform con Firebase, pertanto presuppone una conoscenza di base di Terraform. Prima di iniziare questo workflow, assicurati di aver completato i seguenti prerequisiti.

  • Installa Terraform e acquisisci familiarità con Terraform utilizzando i tutorial ufficiali.

  • Installa Google Cloud CLI (gcloud CLI). Accedi utilizzando un account utente o un service account.

Passaggio 1: crea e personalizza un file di configurazione Terraform

Un file di configurazione Terraform richiede due sezioni principali (descritte in dettaglio di seguito):

Configura provider

La configurazione di provider è obbligatoria indipendentemente dai prodotti o servizi Firebase coinvolti.

  1. Crea un file di configurazione Terraform (ad esempio un file main.tf) nella directory locale.

    In questa guida, utilizzerai questo file di configurazione per specificare sia la configurazione di provider sia tutta l'infrastruttura che vuoi che Terraform crei. Tuttavia, tieni presente che hai diverse opzioni per includere la configurazione del provider.

  2. Includi la seguente configurazione di provider all'inizio del file main.tf.

    Devi utilizzare il provider google-beta perché si tratta di una versione beta dell'utilizzo di Firebase con Terraform. Presta attenzione quando utilizzi questa funzionalità in produzione.

    # Terraform configuration to set up providers by version.
terraform {
  required_providers {
    google-beta = {
      source  = "hashicorp/google-beta"
      version = "~> 6.0"
    }
  }
}

# Configures the provider to use the resource block's specified project for quota checks.
provider "google-beta" {
  user_project_override = true
}

# Configures the provider to not use the resource block's specified project for quota checks.
# This provider should only be used during project creation and initializing services.
provider "google-beta" {
  alias = "no_user_project_override"
  user_project_override = false
}

    Scopri di più sui diversi tipi di attributi relativi ai progetti (tra cui quello che questa guida chiama "progetto di controllo della quota") quando utilizzi Terraform con Firebase.

  3. Vai alla sezione successiva per completare il file di configurazione e specificare l'infrastruttura da creare.

Specifica l'infrastruttura da creare utilizzando i blocchi resource

Nel file di configurazione di Terraform (per questa guida, il file main.tf), devi specificare tutta l'infrastruttura che vuoi che Terraform crei (ovvero tutte le risorse di cui vuoi eseguire il provisioning e tutti i servizi che vuoi attivare). In questa guida troverai un elenco completo di tutte le risorse Firebase che supportano Terraform.

  1. Apri il file main.tf.

  2. Nella configurazione provider, includi la seguente configurazione dei blocchi resource.

    Questo esempio di base crea un nuovo progetto Firebase e poi un'app Firebase per Android all'interno del progetto.

    # Terraform configuration to set up providers by version.
...

# Configures the provider to use the resource block's specified project for quota checks.
...

# Configures the provider to not use the resource block's specified project for quota checks.
...

# Creates a new Google Cloud project.
resource "google_project" "default" {
  provider   = google-beta.no_user_project_override

  name       = "Project Display Name"
  project_id = "project-id-for-new-project"
  # Required for any service that requires the Blaze pricing plan
  # (like Firebase Authentication with GCIP)
  billing_account = "000000-000000-000000"

  # Required for the project to display in any list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "default" {
  provider = google-beta.no_user_project_override
  project  = google_project.default.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebase.googleapis.com",
    # Enabling the ServiceUsage API allows the new project to be quota checked from now on.
    "serviceusage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "default" {
  provider = google-beta
  project  = google_project.default.project_id

  # Waits for the required APIs to be enabled.
  depends_on = [
    google_project_service.default
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "default" {
  provider = google-beta

  project      = google_project.default.project_id
  display_name = "My Awesome Android app"
  package_name = "awesome.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.default,
  ]
}

Passaggio 2: esegui i comandi Terraform per creare l'infrastruttura specificata

Per eseguire il provisioning delle risorse e attivare i servizi specificati nel file main.tf, esegui i seguenti comandi dalla stessa directory del file main.tf. Per informazioni dettagliate su questi comandi, consulta la documentazione di Terraform.

  1. Se è la prima volta che esegui i comandi Terraform nella directory, devi inizializzare la directory di configurazione e installare il provider Google Terraform. Per farlo, esegui questo comando:

    terraform init

  2. Crea l'infrastruttura specificata nel file main.tf eseguendo il seguente comando:

    terraform apply

  3. Verifica che tutto sia stato eseguito o abilitato come previsto:

    • Opzione 1: visualizza la configurazione stampata nel terminale eseguendo il seguente comando:

      terraform show

    • Opzione 2: visualizza il progetto Firebase nella console Firebase.


Risorse Firebase con supporto di Terraform

Le seguenti risorse Firebase e Google sono supportate da Terraform. E aggiungiamo sempre nuove risorse. Quindi, se non vedi la risorsa che vuoi gestire con Terraform, ricontrolla a breve per vedere se è disponibile o richiedila segnalando un problema nel repository GitHub.

Gestione di progetti e app Firebase

  • google_firebase_project: attiva i servizi Firebase su un progetto Google Cloud esistente

  • App Firebase

Firebase Authentication

  • google_identity_platform_config: abilita Google Cloud Identity Platform (GCIP) (che è il backend di Firebase Authentication) e fornisci le impostazioni di autenticazione a livello di progetto

    • La configurazione di Firebase Authentication tramite Terraform richiede l'abilitazione di GCIP. Assicurati di esaminare il file .tf di esempio per scoprire come configurare Firebase Authentication.

    • Il progetto in cui Terraform abiliterà GCIP e/o Firebase Authentication deve essere incluso nel piano tariffario Blaze (ovvero, al progetto deve essere associato un account Cloud Billing). Puoi farlo in modo programmatico impostando l'attributo billing_account nella risorsa google_project.

    • Questa risorsa consente anche di utilizzare altre configurazioni, come i metodi di accesso locali, ad esempio l'autenticazione anonima, tramite email/password e tramite telefono, nonché le funzioni di blocco e i domini autorizzati.

  • google_identity_platform_default_supported_idp_config: configura i provider di identità federati comuni, come Google, Facebook o Apple

  • identity_platform_oauth_idp_config: configura origini di provider di identità (IdP) OAuth arbitrarie

  • google_identity_platform_inbound_saml_config: configura le integrazioni SAML

Non ancora supportati:

  • Configurazione dell'autenticazione a più fattori (MFA) tramite Terraform

Firebase App Hosting

Firebase SQL Connect

Firebase Realtime Database

Non ancora supportati:

Cloud Firestore

  • google_firestore_database: crea un'istanza Cloud Firestore

  • google_firestore_index: abilita query efficienti per Cloud Firestore

  • google_firestore_document: inizializza un'istanza Cloud Firestore con un documento specifico in una raccolta

    Importante: non utilizzare dati reali degli utenti finali o dati di prodotto in questo documento di seed.

Cloud Storage for Firebase

  • google_firebase_storage_bucket: rendi un bucket Cloud Storage esistente accessibile per gli SDK Firebase, l'autenticazione e Firebase Security Rules

  • google_storage_bucket_object: aggiungi un oggetto a un bucket Cloud Storage

    Importante: non utilizzare dati reali degli utenti finali o di produzione in questo file.

Firebase Security Rules (per Cloud Firestore e Cloud Storage)

Tieni presente che Firebase Realtime Database utilizza un sistema di provisioning diverso per il suo Firebase Security Rules.

  • google_firebaserules_ruleset: definisci Firebase Security Rules che si applicano a un'istanza Cloud Firestore o a un bucket Cloud Storage

  • google_firebaserules_release: esegui il deployment di set di regole specifici in un'istanza Cloud Firestore o in un bucket Cloud Storage

Firebase App Check

Firebase Extensions


Esempi di file di configurazione Terraform per casi d'uso comuni


Risoluzione dei problemi e domande frequenti