תחילת העבודה ב-Terraform וב-Firebase

אנחנו מתחילים לתמוך ב-Terraform ב-Firebase. אם אתם חלק מצוות שרוצה להפוך את תהליך היצירה של פרויקטים ב-Firebase לאוטומטי וסטנדרטי, עם הקצאה של משאבים ספציפיים והפעלת שירותים, כדאי לכם להשתמש ב-Terraform עם Firebase.

תהליך העבודה הבסיסי לשימוש ב-Terraform עם Firebase כולל את השלבים הבאים:

  • יצירה והתאמה אישית של קובץ תצורה של Terraform (קובץ .tf) שמציין את התשתית שרוצים להקצות (כלומר, המשאבים שרוצים להקצות והשירותים שרוצים להפעיל).

  • שימוש בפקודות gcloud CLI שמתממשקות עם Terraform כדי להקצות את התשתית שצוינה בקובץ .tf.

מה אפשר לעשות עם Terraform ו-Firebase?

תהליך העבודה הכללי לדוגמה במדריך הזה הוא יצירת פרויקט Firebase חדש עם אפליקציית Android, אבל אפשר לעשות הרבה יותר עם Terraform, למשל:

  • למחוק ולשנות תשתית קיימת באמצעות Terraform.

  • לנהל משימות והגדרות ספציפיות למוצר באמצעות Terraform, כמו:

    • הפעלת Firebase Authentication ספקי כניסה.
    • יצירת קטגוריות או מכונות של מסדי נתונים ב-Cloud Storage ופריסת Firebase Security Rules בשבילן.
    • יצירת Firebase App Hosting קצוות עורפיים, גרסאות build ומשאבים קשורים אחרים.

כדי לבצע את כל המשימות האלה, אתם יכולים להשתמש בפקודות ובקובצי תצורה סטנדרטיים של Terraform. כדי לעזור לכם, סיפקנו קבצי תצורה לדוגמה של Terraform לכמה תרחישים נפוצים.



תהליך עבודה כללי לשימוש ב-Terraform עם Firebase

דרישות מוקדמות

המדריך הזה הוא מבוא לשימוש ב-Terraform עם Firebase, ולכן הוא מניח שיש לכם מיומנות בסיסית ב-Terraform. לפני שמתחילים את תהליך העבודה, חשוב לוודא שהשלמתם את הדרישות המוקדמות הבאות.

  • מתקינים את Terraform ולומדים איך להשתמש בו בעזרת המדריכים הרשמיים.

  • מתקינים את Google Cloud CLI (gcloud CLI) ומתחברים באמצעות חשבון משתמש או חשבון שירות.


שלב 1: יצירה והתאמה אישית של קובץ תצורה של Terraform

קובץ תצורה של Terraform צריך לכלול שני חלקים עיקריים (שמתוארים בפירוט בהמשך):

הגדרת provider

צריך להגדיר provider בכל מקרה, לא משנה באילו מוצרים או שירותים של Firebase משתמשים.

  1. יוצרים קובץ תצורה של Terraform (כמו קובץ main.tf) בספרייה המקומית.

    במדריך הזה תשתמשו בקובץ התצורה כדי לציין את ההגדרה של provider ואת כל התשתית שאתם רוצים ש-Terraform תיצור. עם זאת, שימו לב שיש כמה אפשרויות להגדרת הספק.

  2. מוסיפים את ההגדרה הבאה של provider בחלק העליון של הקובץ main.tf.

    צריך להשתמש בספק google-beta כי זו גרסת בטא של שימוש ב-Firebase עם Terraform. צריך להיזהר כשמשתמשים בה בסביבת ייצור.

    # Terraform configuration to set up providers by version.
    terraform {
      required_providers {
        google-beta = {
          source  = "hashicorp/google-beta"
          version = "~> 6.0"
        }
      }
    }
    
    # Configures the provider to use the resource block's specified project for quota checks.
    provider "google-beta" {
      user_project_override = true
    }
    
    # Configures the provider to not use the resource block's specified project for quota checks.
    # This provider should only be used during project creation and initializing services.
    provider "google-beta" {
      alias = "no_user_project_override"
      user_project_override = false
    }

    מידע נוסף על סוגי המאפיינים השונים שקשורים לפרויקט (כולל מה שנקרא במדריך הזה "פרויקט לבדיקת מכסות") כשמשתמשים ב-Terraform עם Firebase.

  3. כדי להשלים את קובץ התצורה ולציין איזו תשתית ליצור, ממשיכים לקטע הבא.

מציינים איזו תשתית ליצור באמצעות בלוקים של resource

בקובץ התצורה של Terraform (במדריך הזה, הקובץ main.tf), צריך לציין את כל התשתית שרוצים ש-Terraform תיצור (כלומר, כל המשאבים שרוצים להקצות וכל השירותים שרוצים להפעיל). במדריך הזה מופיעה רשימה מלאה של כל משאבי Firebase שתומכים ב-Terraform.

  1. פותחים את הקובץ main.tf.

  2. בהגדרה של provider, כוללים את התצורה הבאה של בלוקים מסוג resource.

    בדוגמה הבסיסית הזו נוצר פרויקט חדש ב-Firebase, ואז נוצרת אפליקציית Firebase ל-Android בתוך הפרויקט הזה.

    # Terraform configuration to set up providers by version.
    ...
    
    # Configures the provider to use the resource block's specified project for quota checks.
    ...
    
    # Configures the provider to not use the resource block's specified project for quota checks.
    ...
    
    # Creates a new Google Cloud project.
    resource "google_project" "default" {
      provider   = google-beta.no_user_project_override
    
      name       = "Project Display Name"
      project_id = "project-id-for-new-project"
      # Required for any service that requires the Blaze pricing plan
      # (like Firebase Authentication with GCIP)
      billing_account = "000000-000000-000000"
    
      # Required for the project to display in any list of Firebase projects.
      labels = {
        "firebase" = "enabled"
      }
    }
    
    # Enables required APIs.
    resource "google_project_service" "default" {
      provider = google-beta.no_user_project_override
      project  = google_project.default.project_id
      for_each = toset([
        "cloudbilling.googleapis.com",
        "cloudresourcemanager.googleapis.com",
        "firebase.googleapis.com",
        # Enabling the ServiceUsage API allows the new project to be quota checked from now on.
        "serviceusage.googleapis.com",
      ])
      service = each.key
    
      # Don't disable the service if the resource block is removed by accident.
      disable_on_destroy = false
    }
    
    # Enables Firebase services for the new project created above.
    resource "google_firebase_project" "default" {
      provider = google-beta
      project  = google_project.default.project_id
    
      # Waits for the required APIs to be enabled.
      depends_on = [
        google_project_service.default
      ]
    }
    
    # Creates a Firebase Android App in the new project created above.
    resource "google_firebase_android_app" "default" {
      provider = google-beta
    
      project      = google_project.default.project_id
      display_name = "My Awesome Android app"
      package_name = "awesome.package.name"
    
      # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
      depends_on = [
        google_firebase_project.default,
      ]
    }


שלב 2: מריצים פקודות Terraform כדי ליצור את התשתית שצוינה

כדי להקצות את המשאבים ולהפעיל את השירותים שצוינו בקובץ main.tf, מריצים את הפקודות הבאות מאותה ספרייה שבה נמצא קובץ main.tf. למידע מפורט על הפקודות האלה, קראו את המסמכים של Terraform.

  1. אם זו הפעם הראשונה שאתם מריצים פקודות Terraform בספרייה, אתם צריכים לאתחל את ספריית ההגדרות ולהתקין את ספק Google Terraform. כדי לעשות את זה, מריצים את הפקודה הבאה:

    terraform init
  2. כדי ליצור את התשתית שצוינה בקובץ main.tf, מריצים את הפקודה הבאה:

    terraform apply
  3. מוודאים שהכול הוקצה או הופעל כצפוי:

    • אפשרות 1: כדי לראות את ההגדרות שמוצגות בטרמינל, מריצים את הפקודה הבאה:

      terraform show
    • אפשרות 2: הצגת הפרויקט ב-Firebase במסוף Firebase.



משאבי Firebase עם תמיכה ב-Terraform

המשאבים הבאים של Firebase ו-Google נתמכים ב-Terraform. אנחנו מוסיפים עוד מקורות מידע כל הזמן. אם אתם לא רואים את המשאב שאתם רוצים לנהל באמצעות Terraform, כדאי לבדוק שוב בקרוב אם הוא זמין או לבקש אותו על ידי דיווח על בעיה במאגר GitHub.


ניהול פרויקטים ואפליקציות ב-Firebase

  • ‫google_firebase_project – הפעלת שירותי Firebase בפרויקט קיים ב-Google Cloud

  • אפליקציות Firebase


Firebase Authentication

  • ‫google_identity_platform_config – הפעלת Google Cloud Identity Platform ‏(GCIP) (שהוא הקצה העורפי של Firebase Authentication) ומתן הגדרות אימות ברמת הפרויקט

    • כדי להגדיר את Firebase Authentication באמצעות Terraform, צריך להפעיל את GCIP. חשוב לעיין בקובץ .tf לדוגמה כדי לראות איך מגדירים את Firebase Authentication.

    • הפרויקט שבו Terraform יפעיל את GCIP או את Firebase Authentication צריך להיות במינוי Blaze בתשלום לפי שימוש (כלומר, לפרויקט צריך להיות חשבון Cloud Billing משויך). כדי לעשות את זה באופן פרוגרמטי, מגדירים את המאפיין billing_account במשאב google_project.

    • המשאב הזה גם מאפשר הגדרות נוספות, כמו שיטות כניסה מקומיות, למשל אימות אנונימי, אימות באמצעות אימייל/סיסמה ואימות באמצעות טלפון, וגם פונקציות חסימה ודומיינים מורשים.

  • ‫google_identity_platform_default_supported_idp_config – הגדרת ספקי זהויות מאוחדים נפוצים, כמו Google, פייסבוק או אפל

  • ‫identity_platform_oauth_idp_config — הגדרת מקורות שרירותיים של ספקי זהויות (IdP) ב-OAuth

  • ‫google_identity_platform_inbound_saml_config — הגדרת שילובים של SAML

עדיין אין תמיכה:

  • הגדרת אימות רב-שלבי (MFA) באמצעות Terraform

Firebase App Hosting


Firebase SQL Connect


Firebase Realtime Database

עדיין אין תמיכה:

  • פריסת Firebase Realtime Database Security Rules באמצעות Terraform (איך פורסים את Security Rules באמצעות כלים אחרים, כולל אפשרויות פרוגרמטיות)

Cloud Firestore

  • ‫google_firestore_database – יצירת מכונה של Cloud Firestore

  • ‫google_firestore_index – הפעלת שאילתות יעילות ל-Cloud Firestore

  • ‫google_firestore_document — הוספת מסמך ספציפי באוסף למופע של Cloud Firestore

    חשוב: אל תשתמשו בנתונים אמיתיים של משתמשי קצה או בנתוני ייצור במסמך הראשוני הזה.


Cloud Storage for Firebase

  • ‫google_firebase_storage_bucket – הפיכת קטגוריה קיימת של Cloud Storage לנגישה לערכות SDK של Firebase, לאימות ול-Firebase Security Rules

  • ‫google_storage_bucket_object – הוספת אובייקט לקטגוריה של Cloud Storage

    חשוב: אל תשתמשו בנתונים אמיתיים של משתמשי קצה או של סביבת הייצור בקובץ הזה.


‫Firebase Security Rules (ל-Cloud Firestore ול-Cloud Storage)

שימו לב שב-Firebase Realtime Database משתמשים במערכת הקצאת הרשאות שונה ל-Firebase Security Rules.

  • ‫google_firebaserules_ruleset – הגדרת Firebase Security Rules שחלים על מכונה של Cloud Firestore או על קטגוריה של Cloud Storage

  • ‫google_firebaserules_release – פריסה של קבוצות כללים ספציפיות למכונה של Cloud Firestore או לקטגוריה של Cloud Storage


Firebase App Check


Firebase Extensions



דוגמאות לקובצי תצורה של Terraform לתרחישים נפוצים



פתרון בעיות ושאלות נפוצות