Erste Schritte mit Terraform und Firebase

Firebase unterstützt jetzt auch Terraform. Wenn Sie in einem Team arbeiten, das die Erstellung von Firebase-Projekten mit bestimmten bereitgestellten Ressourcen und aktivierten Diensten automatisieren und standardisieren möchte, ist die Verwendung von Terraform mit Firebase möglicherweise eine gute Wahl.

Der grundlegende Workflow für die Verwendung von Terraform mit Firebase umfasst Folgendes:

  • Erstellen und Anpassen einer Terraform-Konfigurationsdatei (eine .tf-Datei), in der die Infrastruktur angegeben wird, die Sie bereitstellen möchten (d. h. die Ressourcen, die Sie bereitstellen möchten, und die Dienste, die Sie aktivieren möchten).

  • Verwenden Sie gcloud CLI-Befehle, die mit Terraform interagieren, um die in der Datei .tf angegebene Infrastruktur bereitzustellen.

Was können Sie mit Terraform und Firebase tun?

Im Beispiel für einen allgemeinen Workflow in diesem Leitfaden wird ein neues Firebase-Projekt mit einer Android-App erstellt. Mit Terraform können Sie aber noch viel mehr tun, z. B.:

  • Vorhandene Infrastruktur mit Terraform löschen und ändern

  • Produktspezifische Konfigurationen und Aufgaben mit Terraform verwalten, z. B.:

    • Firebase Authentication Anbieter für Anmeldungen werden aktiviert.
    • Cloud Storage-Buckets oder Datenbankinstanzen erstellen und Firebase Security Rules dafür bereitstellen.
    • Erstellen von Firebase App Hosting-Back-Ends, -Builds und anderen zugehörigen Ressourcen.

Sie können alle diese Aufgaben mit Standard-Terraform-Konfigurationsdateien und -Befehlen ausführen. Dazu stellen wir Terraform-Beispielkonfigurationsdateien für mehrere gängige Anwendungsfälle bereit.


Allgemeiner Workflow für die Verwendung von Terraform mit Firebase

Voraussetzungen

Dieser Leitfaden ist eine Einführung in die Verwendung von Terraform mit Firebase. Es werden daher grundlegende Kenntnisse von Terraform vorausgesetzt. Prüfen Sie, ob die folgenden Voraussetzungen erfüllt sind, bevor Sie mit diesem Workflow beginnen.

  • Installieren Sie Terraform und machen Sie sich anhand der offiziellen Tutorials mit Terraform vertraut.

  • Installieren Sie die Google Cloud CLI (gcloud CLI). Melden Sie sich mit einem Nutzerkonto oder einem Dienstkonto an.

Schritt 1: Terraform-Konfigurationsdatei erstellen und anpassen

Eine Terraform-Konfigurationsdatei benötigt zwei Hauptabschnitte (die unten im Detail beschrieben werden):

provider einrichten

Eine provider-Einrichtung ist unabhängig von den beteiligten Firebase-Produkten oder -Diensten erforderlich.

  1. Erstellen Sie in Ihrem lokalen Verzeichnis eine Terraform-Konfigurationsdatei (z. B. eine main.tf-Datei).

    In dieser Anleitung verwenden Sie diese Konfigurationsdatei, um sowohl die provider-Einrichtung als auch die gesamte Infrastruktur anzugeben, die Terraform erstellen soll. Sie haben jedoch verschiedene Möglichkeiten, die Anbieterkonfiguration einzubinden.

  2. Fügen Sie die folgende provider-Einrichtung oben in der Datei main.tf ein.

    Sie müssen den Anbieter google-beta verwenden, da es sich um eine Betaversion der Verwendung von Firebase mit Terraform handelt. Seien Sie vorsichtig, wenn Sie sie in der Produktion verwenden.

    # Terraform configuration to set up providers by version.
terraform {
  required_providers {
    google-beta = {
      source  = "hashicorp/google-beta"
      version = "~> 6.0"
    }
  }
}

# Configures the provider to use the resource block's specified project for quota checks.
provider "google-beta" {
  user_project_override = true
}

# Configures the provider to not use the resource block's specified project for quota checks.
# This provider should only be used during project creation and initializing services.
provider "google-beta" {
  alias = "no_user_project_override"
  user_project_override = false
}

    Weitere Informationen zu den verschiedenen Arten von projektbezogenen Attributen (einschließlich des in diesem Leitfaden als „Kontingentprüfprojekt“ bezeichneten Projekts) bei der Verwendung von Terraform mit Firebase.

  3. Fahren Sie mit dem nächsten Abschnitt fort, um die Konfigurationsdatei fertigzustellen und anzugeben, welche Infrastruktur erstellt werden soll.

Mit resource-Blöcken angeben, welche Infrastruktur erstellt werden soll

In Ihrer Terraform-Konfigurationsdatei (für diese Anleitung die Datei main.tf) müssen Sie die gesamte Infrastruktur angeben, die Terraform erstellen soll. Das bedeutet, dass Sie alle Ressourcen angeben müssen, die Sie bereitstellen möchten, und alle Dienste, die Sie aktivieren möchten. In diesem Leitfaden finden Sie eine vollständige Liste aller Firebase-Ressourcen, die Terraform unterstützen.

  1. Öffnen Sie Ihre main.tf-Datei.

  2. Fügen Sie unter der Einrichtung von provider die folgende Konfiguration von resource-Blöcken ein.

    In diesem einfachen Beispiel wird ein neues Firebase-Projekt und dann eine Firebase-Android-App in diesem Projekt erstellt.

    # Terraform configuration to set up providers by version.
...

# Configures the provider to use the resource block's specified project for quota checks.
...

# Configures the provider to not use the resource block's specified project for quota checks.
...

# Creates a new Google Cloud project.
resource "google_project" "default" {
  provider   = google-beta.no_user_project_override

  name       = "Project Display Name"
  project_id = "project-id-for-new-project"
  # Required for any service that requires the Blaze pricing plan
  # (like Firebase Authentication with GCIP)
  billing_account = "000000-000000-000000"

  # Required for the project to display in any list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "default" {
  provider = google-beta.no_user_project_override
  project  = google_project.default.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebase.googleapis.com",
    # Enabling the ServiceUsage API allows the new project to be quota checked from now on.
    "serviceusage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "default" {
  provider = google-beta
  project  = google_project.default.project_id

  # Waits for the required APIs to be enabled.
  depends_on = [
    google_project_service.default
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "default" {
  provider = google-beta

  project      = google_project.default.project_id
  display_name = "My Awesome Android app"
  package_name = "awesome.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.default,
  ]
}

Schritt 2: Terraform-Befehle ausführen, um die angegebene Infrastruktur zu erstellen

Führen Sie die folgenden Befehle im selben Verzeichnis wie die Datei main.tf aus, um die Ressourcen bereitzustellen und die in der Datei main.tf angegebenen Dienste zu aktivieren. Detaillierte Informationen zu diesen Befehlen finden Sie in der Terraform-Dokumentation.

  1. Wenn Sie Terraform-Befehle zum ersten Mal im Verzeichnis ausführen, müssen Sie das Konfigurationsverzeichnis initialisieren und den Google Terraform-Anbieter installieren. Führen Sie dazu den folgenden Befehl aus:

    terraform init

  2. Erstellen Sie die in der Datei main.tf angegebene Infrastruktur mit dem folgenden Befehl:

    terraform apply

  3. Prüfen Sie, ob alles wie erwartet bereitgestellt oder aktiviert wurde:

    • Option 1: Führen Sie den folgenden Befehl aus, um die Konfiguration in Ihrem Terminal anzeigen zu lassen:

      terraform show

    • Option 2: Firebase-Projekt in der Firebase Console ansehen.


Firebase-Ressourcen mit Terraform-Unterstützung

Die folgenden Firebase- und Google-Ressourcen werden von Terraform unterstützt. Und wir fügen ständig neue Ressourcen hinzu. Wenn Sie die Ressource, die Sie mit Terraform verwalten möchten, nicht sehen, schauen Sie bald wieder vorbei, um zu sehen, ob sie verfügbar ist, oder fordern Sie sie an, indem Sie ein Problem im GitHub-Repository melden.

Firebase-Projekt- und App-Verwaltung

  • google_firebase_project: Firebase-Dienste in einem vorhandenen Google Cloud-Projekt aktivieren

  • Firebase-Apps

Firebase Authentication

Noch nicht unterstützt:

  • Multi-Faktor-Authentifizierung (MFA) über Terraform konfigurieren

Firebase App Hosting

Firebase SQL Connect

Firebase Realtime Database

Noch nicht unterstützt:

Cloud Firestore

  • google_firestore_database: Erstellen Sie eine Cloud Firestore-Instanz.

  • google_firestore_index: Ermöglicht effiziente Abfragen für Cloud Firestore.

  • google_firestore_document: Eine Cloud Firestore-Instanz mit einem bestimmten Dokument in einer Sammlung füllen

    Wichtig: Verwenden Sie in diesem Seed-Dokument keine echten Endnutzer- oder Produktionsdaten.

Cloud Storage for Firebase

  • google_firebase_storage_bucket: Einen vorhandenen Cloud Storage-Bucket für Firebase SDKs, Authentifizierung und Firebase Security Rules zugänglich machen

  • google_storage_bucket_object: Objekt zu einem Cloud Storage-Bucket hinzufügen

    Wichtig: Verwenden Sie in dieser Datei keine echten Endnutzer- oder Produktionsdaten.

Firebase Security Rules (für Cloud Firestore und Cloud Storage)

Beachten Sie, dass Firebase Realtime Database ein anderes Bereitstellungssystem für seine Firebase Security Rules verwendet.

  • google_firebaserules_ruleset: Definieren Sie Firebase Security Rules, die für eine Cloud Firestore-Instanz oder einen Cloud Storage-Bucket gelten.

  • google_firebaserules_release: Bestimmte Regelsätze in einer Cloud Firestore-Instanz oder einem Cloud Storage-Bucket bereitstellen

Firebase App Check

Firebase Extensions


Beispiel-Terraform-Konfigurationsdateien für gängige Anwendungsfälle


Fehlerbehebung und häufig gestellte Fragen