Erste Schritte mit Terraform und Firebase

Terraform wird in Firebase nach und nach unterstützt. Wenn Sie in einem Team arbeiten, das das Erstellen von Firebase-Projekten mit bestimmten bereitgestellten Ressourcen und aktivierten Diensten automatisieren und standardisieren möchte, ist die Verwendung von Terraform mit Firebase eine gute Lösung.

Der grundlegende Workflow für die Verwendung von Terraform mit Firebase umfasst Folgendes:

  • Erstellen und Anpassen einer Terraform-Konfigurationsdatei (.tf-Datei), in der die zu bereitstellende Infrastruktur angegeben ist (d. h. die zu bereitstellenden Ressourcen und die zu aktivierenden Dienste).

  • Mit gcloud CLI-Befehlen, die mit Terraform interagieren, um die in der .tf-Datei angegebene Infrastruktur bereitzustellen.

Was können Sie mit Terraform und Firebase tun?

Im Beispiel für einen allgemeinen Workflow in diesem Leitfaden wird ein neues Firebase-Projekt mit einer Android-App erstellt. Mit Terraform können Sie jedoch noch viel mehr tun, z. B.:

  • Vorhandene Infrastruktur mit Terraform löschen und ändern

  • Produktspezifische Konfiguration und Aufgaben mit Terraform verwalten, z. B.:

    • Anbieter für Anmeldungen bei Firebase Authentication aktivieren
    • Cloud Storage-Buckets oder Datenbankinstanzen erstellen und Firebase Security Rules für sie bereitstellen

Sie können Standard-Terraform-Konfigurationsdateien und ‑Befehle verwenden, um alle diese Aufgaben auszuführen. Zur Unterstützung haben wir Beispiel-Terraform-Konfigurationsdateien für verschiedene gängige Anwendungsfälle bereitgestellt.


Allgemeiner Ablauf für die Verwendung von Terraform mit Firebase

Voraussetzungen

Dieser Leitfaden ist eine Einführung in die Verwendung von Terraform mit Firebase. Es wird daher vorausgesetzt, dass Sie mit Terraform vertraut sind. Bevor Sie mit diesem Workflow beginnen, müssen Sie die folgenden Voraussetzungen erfüllen.

  • Installieren Sie Terraform und machen Sie sich mit den offiziellen Anleitungen mit Terraform vertraut.

  • Installieren Sie die Google Cloud CLI (gcloud CLI). Melden Sie sich mit einem Nutzerkonto oder einem Dienstkonto an.

Schritt 1:Terraform-Konfigurationsdatei erstellen und anpassen

Eine Terraform-Konfigurationsdatei benötigt zwei Hauptabschnitte, die unten ausführlich beschrieben werden:

provider einrichten

Eine provider-Einrichtung ist unabhängig von den verwendeten Firebase-Produkten oder ‑Diensten erforderlich.

  1. Erstellen Sie eine Terraform-Konfigurationsdatei (z. B. eine main.tf-Datei) in Ihrem lokalen Verzeichnis.

    In dieser Anleitung verwenden Sie diese Konfigurationsdatei, um sowohl die provider-Einrichtung als auch die gesamte Infrastruktur anzugeben, die Terraform erstellen soll. Sie haben jedoch verschiedene Möglichkeiten, die Anbietereinrichtung einzubinden.

  2. Fügen Sie die folgende provider-Einrichtung oben in die Datei main.tf ein.

    Sie müssen den Anbieter google-beta verwenden, da dies ein Betarelease der Verwendung von Firebase mit Terraform ist. Seien Sie bei der Verwendung in der Produktion vorsichtig.

    # Terraform configuration to set up providers by version.
terraform {
  required_providers {
    google-beta = {
      source  = "hashicorp/google-beta"
      version = "~> 6.0"
    }
  }
}

# Configures the provider to use the resource block's specified project for quota checks.
provider "google-beta" {
  user_project_override = true
}

# Configures the provider to not use the resource block's specified project for quota checks.
# This provider should only be used during project creation and initializing services.
provider "google-beta" {
  alias = "no_user_project_override"
  user_project_override = false
}

    Weitere Informationen zu den verschiedenen Arten von projektbezogenen Attributen (einschließlich des in diesem Leitfaden als „Quota-Check-Projekt“ bezeichneten Projekts) bei der Verwendung von Terraform mit Firebase

  3. Fahren Sie mit dem nächsten Abschnitt fort, um die Konfigurationsdatei fertigzustellen und anzugeben, welche Infrastruktur erstellt werden soll.

Mit resource-Blöcken angeben, welche Infrastruktur erstellt werden soll

In Ihrer Terraform-Konfigurationsdatei (in diesem Leitfaden die main.tf-Datei) müssen Sie die gesamte Infrastruktur angeben, die Terraform erstellen soll. Das sind alle Ressourcen, die Sie bereitstellen möchten, und alle Dienste, die Sie aktivieren möchten. In diesem Leitfaden finden Sie eine vollständige Liste aller Firebase-Ressourcen, die Terraform unterstützen.

  1. Öffnen Sie Ihre main.tf-Datei.

  2. Fügen Sie in der provider-Einrichtung die folgende Konfiguration von resource-Blöcken ein.

    In diesem einfachen Beispiel wird ein neues Firebase-Projekt erstellt und dann eine Firebase-Android-App in diesem Projekt.

    # Terraform configuration to set up providers by version.
...

# Configures the provider to use the resource block's specified project for quota checks.
...

# Configures the provider to not use the resource block's specified project for quota checks.
...

# Creates a new Google Cloud project.
resource "google_project" "default" {
  provider   = google-beta.no_user_project_override

  name       = "Project Display Name"
  project_id = "project-id-for-new-project"
  # Required for any service that requires the Blaze pricing plan
  # (like Firebase Authentication with GCIP)
  billing_account = "000000-000000-000000"

  # Required for the project to display in any list of Firebase projects.
  labels = {
    "firebase" = "enabled"
  }
}

# Enables required APIs.
resource "google_project_service" "default" {
  provider = google-beta.no_user_project_override
  project  = google_project.default.project_id
  for_each = toset([
    "cloudbilling.googleapis.com",
    "cloudresourcemanager.googleapis.com",
    "firebase.googleapis.com",
    # Enabling the ServiceUsage API allows the new project to be quota checked from now on.
    "serviceusage.googleapis.com",
  ])
  service = each.key

  # Don't disable the service if the resource block is removed by accident.
  disable_on_destroy = false
}

# Enables Firebase services for the new project created above.
resource "google_firebase_project" "default" {
  provider = google-beta
  project  = google_project.default.project_id

  # Waits for the required APIs to be enabled.
  depends_on = [
    google_project_service.default
  ]
}

# Creates a Firebase Android App in the new project created above.
resource "google_firebase_android_app" "default" {
  provider = google-beta

  project      = google_project.default.project_id
  display_name = "My Awesome Android app"
  package_name = "awesome.package.name"

  # Wait for Firebase to be enabled in the Google Cloud project before creating this App.
  depends_on = [
    google_firebase_project.default,
  ]
}

Schritt 2:Terraform-Befehle ausführen, um die angegebene Infrastruktur zu erstellen

Führen Sie die folgenden Befehle im selben Verzeichnis wie die Datei main.tf aus, um die in der Datei main.tf angegebenen Ressourcen bereitzustellen und die Dienste zu aktivieren. Ausführliche Informationen zu diesen Befehlen finden Sie in der Terraform-Dokumentation.

  1. Wenn Sie zum ersten Mal Terraform-Befehle in diesem Verzeichnis ausführen, müssen Sie das Konfigurationsverzeichnis initialisieren und den Google Terraform-Anbieter installieren. Führen Sie dazu den folgenden Befehl aus:

    terraform init

  2. Erstellen Sie die in der main.tf-Datei angegebene Infrastruktur mit dem folgenden Befehl:

    terraform apply

  3. Prüfen Sie, ob alles wie erwartet bereitgestellt oder aktiviert wurde:

    • Option 1:Führen Sie den folgenden Befehl aus, um die Konfiguration im Terminal zu sehen:

      terraform show

    • Option 2:Rufen Sie Ihr Firebase-Projekt in der Firebase Console auf.


Firebase-Ressourcen mit Terraform-Unterstützung

Die folgenden Firebase- und Google-Ressourcen werden von Terraform unterstützt. Und wir fügen laufend weitere Ressourcen hinzu. Wenn Sie die Ressource, die Sie mit Terraform verwalten möchten, nicht sehen, sehen Sie bald noch einmal nach, ob sie verfügbar ist, oder erstellen Sie ein Problem im GitHub-Repository, um sie anzufordern.

Firebase-Projekt- und App-Verwaltung

  • google_firebase_project: Firebase-Dienste in einem vorhandenen Google Cloud-Projekt aktivieren

  • Firebase-Apps

Firebase Authentication

  • google_identity_platform_config: Aktivieren Sie Google Cloud Identity Platform (GCIP), das Backend für Firebase Authentication, und geben Sie Authentifizierungseinstellungen auf Projektebene an.

    • Wenn Sie Firebase Authentication über Terraform konfigurieren möchten, müssen Sie GCIP aktivieren. In der Beispieldatei .tf finden Sie Informationen zum Einrichten von Firebase Authentication.

    • Für das Projekt, in dem Terraform GCIP und/oder Firebase Authentication aktiviert, muss der Blaze-Preisplan verwendet werden. Das bedeutet, dass dem Projekt ein Cloud Billing-Konto zugewiesen sein muss. Das geht programmatisch, indem du das Attribut billing_account in der google_project-Ressource festlegst.

    • Diese Ressource ermöglicht auch mehr Konfigurationen, z. B. lokale Anmeldemethoden wie anonyme, E-Mail-/Passwort- und Telefonauthentifizierung sowie Blockierfunktionen und autorisierte Domains.

  • google_identity_platform_default_supported_idp_config: Konfigurieren gängiger föderierter Identitätsanbieter wie Google, Facebook oder Apple

  • identity_platform_oauth_idp_config – beliebige OAuth-Identitätsanbieterquellen (IdP) konfigurieren

  • google_identity_platform_inbound_saml_config: SAML-Integrationen konfigurieren

Noch nicht unterstützt:

  • Multi-Faktor-Authentifizierung (MFA) über Terraform konfigurieren

Firebase Data Connect

Firebase Realtime Database

Noch nicht unterstützt:

Cloud Firestore

  • google_firestore_database: Cloud Firestore-Instanz erstellen

  • google_firestore_index: Cloud Firestore-Effiziente Abfragen aktivieren

  • google_firestore_document: Cloud Firestore-Instanz mit einem bestimmten Dokument in einer Sammlung initialisieren

    Wichtig:Verwenden Sie in diesem Seed-Dokument keine echten Endnutzer- oder Produktionsdaten.

Cloud Storage for Firebase

  • google_firebase_storage_bucket: Mit diesem Befehl können Sie einen vorhandenen Cloud Storage-Bucket für Firebase SDKs, Authentifizierung und Firebase Security Rules zugänglich machen.

  • google_storage_bucket_object: einem Cloud Storage-Bucket ein Objekt hinzufügen

    Wichtig:Verwenden Sie in dieser Datei keine echten Endnutzer- oder Produktionsdaten.

Firebase Security Rules (für Cloud Firestore und Cloud Storage)

Hinweis: Firebase Realtime Database verwendet ein anderes Bereitstellungssystem für seine Firebase Security Rules.

  • google_firebaserules_ruleset: Hiermit können Sie Firebase Security Rules für eine Cloud Firestore-Instanz oder einen Cloud Storage-Bucket definieren.

  • google_firebaserules_release: Bestimmte Regelsätze auf einer Cloud Firestore-Instanz oder einem Cloud Storage-Bucket bereitstellen

Firebase App Check

Firebase Extensions


Beispiel-Terraform-Konfigurationsdateien für gängige Anwendungsfälle


Fehlerbehebung und häufig gestellte Fragen